Not able to setup timer interrupt in nRF51822

RE: Not able to setup timer interrupt in nRF51822

NK99 — Mon, 06 Feb 2017 08:55:23 GMT

I followed your instructions on issue and i had very nice results. I am trying to control a dc motor with a very fast encoder with redbear ble nano and i was wondering if you have any suggestions. I used your code for the pid command but im still having trouble reading the encoder and i was wondering if i can have more time interrupts? Maybe something with the qdec peripheral? Need help!!!

RE: Not able to setup timer interrupt in nRF51822

adrianwong — Tue, 05 Jan 2016 08:23:46 GMT

Thank you so much Monpetit!!! I solved it.

RE: Not able to setup timer interrupt in nRF51822

adrianwong — Tue, 05 Jan 2016 07:56:24 GMT

Now it is working and displaying "Entered 1". I realized that add this line "if ((tCount % 300) == 0)" make the difference. What is the reason?

RE: Not able to setup timer interrupt in nRF51822

adrianwong — Tue, 05 Jan 2016 07:51:52 GMT

okay. I try changing comp1 to have the timer interval of 1s. but is not working.

RE: Not able to setup timer interrupt in nRF51822

monpetit — Tue, 05 Jan 2016 07:44:37 GMT

adrianwong, your code differs from my code. And please copy and paste my code exactly. My code separates function prototype and body.

I've just modified my code corresponding to your new code with Arduino 1.6.7 and BLE Nano v1.5(32KB). I don't know how long timer interval do you want. But my code print out 'Entered 1'.

RE: Not able to setup timer interrupt in nRF51822

adrianwong — Tue, 05 Jan 2016 07:21:05 GMT

Now i realized that after going into the "start_timer()" function it couldn't come out. As i put a printout after start_timer() inside the setup(), nothing is printed out. Any idea?

RE: Not able to setup timer interrupt in nRF51822

adrianwong — Tue, 05 Jan 2016 06:39:44 GMT

Thank. Now i able to get into interrupt function but now having another problems

RE: Not able to setup timer interrupt in nRF51822

adrianwong — Tue, 05 Jan 2016 06:25:58 GMT

Hi, I already posted a new code. please check out the "Timer_Interrupt.txt". I able to make it displaying "Entered 3" but in a very rapid speed even though after manipulating the value of "comp1". Besides that, I cannot see any display of "Entered 1" so i assume the loop() is not working.

RE: Not able to setup timer interrupt in nRF51822

RK — Tue, 05 Jan 2016 06:23:44 GMT

Monpetit answered your question - it's C++ vs C linkage and it would have helped if you'd pointed out you were using Arduino build environment at the start. You need to figure out how to fix the compilation error you're getting - which means starting by working out where the previous definition comes from which is using C++ linkage.

RE: Not able to setup timer interrupt in nRF51822

adrianwong — Tue, 05 Jan 2016 06:01:45 GMT

Yes I did.

RE: Not able to setup timer interrupt in nRF51822

monpetit — Tue, 05 Jan 2016 05:36:23 GMT

Did you copy and paste my code?

RE: Not able to setup timer interrupt in nRF51822

adrianwong — Tue, 05 Jan 2016 05:32:17 GMT

I couldn't compile. These are the errors : error: conflicts with new declaration with 'C' linkage previous declaration of 'void TIMER1_IRQHandler()' with 'C++' linkage

RE: Not able to setup timer interrupt in nRF51822

adrianwong — Tue, 05 Jan 2016 04:36:33 GMT

Ok. I will give it a try and let you know soon.

RE: Not able to setup timer interrupt in nRF51822

adrianwong — Tue, 05 Jan 2016 04:35:51 GMT

I already try flashing of LED. But still getting the same result.

RE: Not able to setup timer interrupt in nRF51822

adrianwong — Tue, 05 Jan 2016 04:35:04 GMT

Ya. In Arduino IDE. I'm using a library that can compile nordic code in Arduino IDE

RE: Not able to setup timer interrupt in nRF51822

monpetit — Tue, 05 Jan 2016 01:48:54 GMT

Arduino source code is compiled as C++, but IRQ Handler is linked as C. So you have to declare void TIMER1_IRQHandler(void) with C linkage.

#include <nrf.h>

#ifdef __cplusplus
extern "C" {
#endif
void TIMER1_IRQHandler(void);
#ifdef __cplusplus
}
#endif

// count to us (micro seconds) conversion factor
// set in start_timer()
static volatile float countToUs = 1;

// counter
static volatile uint32_t tCount = 0;


// set up and start Timer1
void start_timer(void)
{
    NRF_TIMER1->MODE = TIMER_MODE_MODE_Timer;
    NRF_TIMER1->TASKS_CLEAR = 1;
    // set prescalar n
    // f = 16 MHz / 2^(n)
    uint8_t prescaler = 0;
    NRF_TIMER1->PRESCALER = prescaler;
    NRF_TIMER1->BITMODE = TIMER_BITMODE_BITMODE_16Bit;

    // 16 MHz clock generates timer tick every 1/(16000000) s = 62.5 nano s
    // With compare enabled, the interrupt is fired every: 62.5 * comp1 nano s
    // = 0.0625*comp1 micro seconds
    // multiply this by 2^(prescalar)

    uint16_t comp1 = 500;
    // set compare
    NRF_TIMER1->CC[1] = comp1;

    // set conversion factor
    countToUs = 0.0625 * comp1 * (1 << prescaler);

    //printf("timer tick = %f us\n", countToUs);

    // enable compare 1
    NRF_TIMER1->INTENSET =
        (TIMER_INTENSET_COMPARE1_Enabled << TIMER_INTENSET_COMPARE1_Pos);

    // use the shorts register to clear compare 1
    NRF_TIMER1->SHORTS = (TIMER_SHORTS_COMPARE1_CLEAR_Enabled <<
                          TIMER_SHORTS_COMPARE1_CLEAR_Pos);

    // enable IRQ
    NVIC_EnableIRQ(TIMER1_IRQn);

    Serial.println("Entered 2");

    // start timer
    NRF_TIMER1->TASKS_START = 1;

}

// Timer 1 IRQ handler
// just increment count
void TIMER1_IRQHandler(void)
{
    Serial.println("Entered 3");

    if (NRF_TIMER1->EVENTS_COMPARE[1] &&
            NRF_TIMER1->INTENSET & TIMER_INTENSET_COMPARE1_Msk) {

        // clear compare register event
        NRF_TIMER1->EVENTS_COMPARE[1] = 0;

        // increment count
        tCount++;
    }
}

void setup()
{
    // put your setup code here, to run once:
    Serial.begin(9600);

    delay(2000);

    start_timer();
}

void loop()
{
    // put your main code here, to run repeatedly:
    Serial.println("Entered 1");
}

Good Luck! :)

New code:

#include <nrf.h>

// count to us (micro seconds) conversion factor
// set in start_timer()
static volatile float countToUs = 1;

// counter
static volatile uint32_t tCount = 0;


#ifdef __cplusplus
extern "C" {
#endif
void TIMER1_IRQHandler(void);
#ifdef __cplusplus
}
#endif


// Timer 1 IRQ handler
// just increment count
void TIMER1_IRQHandler(void)
{
    if (NRF_TIMER1->EVENTS_COMPARE[1] &&
            NRF_TIMER1->INTENSET & TIMER_INTENSET_COMPARE1_Msk) {

        // clear compare register event
        NRF_TIMER1->EVENTS_COMPARE[1] = 0;

        // increment count
        tCount++;

        if ((tCount % 300) == 0)
            Serial.println("Entered 3");
    }
}


// set up and start Timer1
void start_timer(void)
{
    NRF_TIMER1->MODE = TIMER_MODE_MODE_Timer;
    NRF_TIMER1->TASKS_CLEAR = 1;
    // set prescalar n
    // f = 16 MHz / 2^(n)
    uint8_t prescaler = 0;
    NRF_TIMER1->PRESCALER = prescaler;
    NRF_TIMER1->BITMODE = TIMER_BITMODE_BITMODE_16Bit;

    // 16 MHz clock generates timer tick every 1/(16000000) s = 62.5 nano s
    // With compare enabled, the interrupt is fired every: 62.5 * comp1 nano s
    // = 0.0625*comp1 micro seconds
    // multiply this by 2^(prescalar)

    uint16_t comp1 = 500;
    // set compare
    NRF_TIMER1->CC[1] = comp1;

    // set conversion factor
    countToUs = 0.0625 * comp1 * (1 << prescaler);

    //printf("timer tick = %f us\n", countToUs);

    // enable compare 1
    NRF_TIMER1->INTENSET =
        (TIMER_INTENSET_COMPARE1_Enabled << TIMER_INTENSET_COMPARE1_Pos);

    // use the shorts register to clear compare 1
    NRF_TIMER1->SHORTS = (TIMER_SHORTS_COMPARE1_CLEAR_Enabled <<
                          TIMER_SHORTS_COMPARE1_CLEAR_Pos);

    // enable IRQ
    NVIC_EnableIRQ(TIMER1_IRQn);

    Serial.println("Entered 2");

    // start timer
    NRF_TIMER1->TASKS_START = 1;

}

void setup()
{
    // put your setup code here, to run once:
    Serial.begin(9600);

    delay(2000);

    start_timer();
}

void loop()
{
    // put your main code here, to run repeatedly:
    Serial.println("Entered 1");
    __WFE();
}

RE: Not able to setup timer interrupt in nRF51822

RK — Mon, 04 Jan 2016 16:35:48 GMT

That code looks very Arduino, with the setup and loop() stuff. What board are you using, what development environment?

RE: Not able to setup timer interrupt in nRF51822

Stefan Birnir Sverrisson — Mon, 04 Jan 2016 15:09:33 GMT

Hmm, cant quickly see anything wrong with your code either. You could try to lower the interrupt frequency to see if that helps. You could also try to flash a LED instead of writing to serial, to see if that makes a difference.

RE: Not able to setup timer interrupt in nRF51822

adrianwong — Mon, 04 Jan 2016 07:03:56 GMT

Hi, I already tried to follow the example setup and i still stuck at the initialisation "start_timer()" as i only can see "Entered 2" is printed out. I think my code in timer_interrupt.txt had configured the timer accordingly. Kindly assist. Thanks.

RE: Not able to setup timer interrupt in nRF51822

adrianwong — Mon, 04 Jan 2016 06:35:44 GMT

yes. This is the only code. I want to make sure the timer interrupt is working first before adding in anything to it. But so far it is still not working. I stuck at the initialisation "start_timer()" as i only can see "Entered 2" is printed out. If I comment out "start_timer()" function then i can see the print out of "Entered 1" only. Kindly assist. Thanks.

RE: Not able to setup timer interrupt in nRF51822

Michael Dietz — Sat, 02 Jan 2016 03:19:50 GMT

A timer is configured and interrupt handler is set in this example:

github.com/.../main.c

also for other peripherals

RE: Not able to setup timer interrupt in nRF51822

Martijn — Thu, 31 Dec 2015 21:39:36 GMT

When I look at this code I can't find any errors. Is there more code running, or is this the only code?